USE [Elyse_DB]
GO
/****** Object:  StoredProcedure [controlling].[usp_DEL_contr_doc_group_link]    Script Date: Sat 05-09-2026 7:01:55 AM ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author:		Silkwood Software
-- Create date: 05-09-2024
-- Description:	Initial creation
-- Deletes a document to controller level document group link.
-- Input is a document id and a controller level document group ID.
-- Output is a message and transaction status
/*
COPYRIGHT NOTICE
This database schema and stored procedures are protected by copyright.
Copyright.  Silkwood Software Pty. Ltd. 2024
*/

-- =============================================
CREATE PROCEDURE [controlling].[usp_DEL_contr_doc_group_link]

     @documentid nvarchar(50)         = '', 
	 @recordid bigint                 = NULL,
	 @notes nvarchar(1000)            = '',  -- Optional
	 @app_reference nvarchar(1000)    = '',  -- Optional
	 @message nvarchar(1000)          = NULL OUTPUT,
	 @transaction_status nvarchar(50) = NULL OUTPUT

AS
BEGIN
	-- SET NOCOUNT ON added to prevent extra result sets from
	-- interfering with SELECT statements.
	SET NOCOUNT ON;

	DECLARE
	    @connectedusersid varbinary(100)        = SUSER_SID(ORIGINAL_LOGIN()),   -- The SID of the connected user
	    @username nvarchar(150)                 = ORIGINAL_LOGIN(),     -- The username 
		@sidid bigint                           = NULL, 
		@contrdocgroupname nvarchar(50)         = '',
		@tempuserauth_status nchar(10)          = '',     -- Temporary value for authentication sp.
		@userauthentication_status nchar(10)    = 'Fail', -- The outcome of the authentication check of the user 
		                                                  -- Defaults to Fail until it is set to Pass.
		@tempmessage nvarchar(300)              = '',
		@docauthenticationstatus nchar(10)      = '',  -- Communicates if the user is not authorised to access the document
		                                               -- or alternatively if the document does not exist.  The result does not distinguish either. 
		@transaction_ready nchar(10)            = 'Ready',
		@data_validation_status nchar(10)       = 'Pass';

  -- Parameters which have been initialised at declaration but not explicitly set might be output as null to calling functions.
  SET @transaction_status = 'Transaction not attempted';  


-- Connected user authentication

  -- Authenticate the connected users for the role
  EXEC [internal].[usp_AUTHENTICATE_user_role] 
        @role_to_check = 'Controller',
		@user_authentication_result = @tempuserauth_status OUTPUT;
  IF @tempuserauth_status = 'Pass'   SET @userauthentication_status = 'Pass';

  IF @userauthentication_status = 'Fail'
    BEGIN  -- The user does not have permission for this action
	    SET @userauthentication_status = 'Fail';
		SET @transaction_ready         = 'Fail';
	    EXEC internal.usp_SEL_message 
            @message_id   = 'NoPermission', 
			@message_text = @tempmessage OUTPUT;
	    IF (@tempmessage IS NOT NULL) 
  	       SET @message = CONCAT(@message, ' | ', ISNULL(@username, ''), '  ', @tempmessage);
	    ELSE 
		   SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on NoPermission');
	END

  IF @userauthentication_status = 'Pass' -- Don't do anything if the user is not authorised.
    BEGIN
		  -- Data validation

		 IF @documentid = ''
			SET @documentid = NULL;
		  IF @documentid IS NULL
			 BEGIN -- A document id has not been supplied
			   SET @data_validation_status = 'Fail';
			   SET @transaction_ready      = 'Fail';
			   EXEC internal.usp_SEL_message 
					@message_id = 'NoDocID', 
					@message_text = @tempmessage OUTPUT;
  			   IF (@tempmessage IS NOT NULL) 
				   SET @message = CONCAT_WS(' | ', @message, @tempmessage);
			   ELSE 
				   SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on NoDocID.');
			 END
		  ELSE  -- doc id has been supplied
				BEGIN -- Check if the document ID exists and the user has edit permission for the document
				   EXEC [internal].[usp_AUTHENTICATE_doc_ed_perm] 
 						@doc_id_to_check_ep =  @documentid,
						@user_authentication_result_dep = @docauthenticationstatus OUTPUT;
					 IF @docauthenticationstatus = 'Fail'
						 BEGIN -- Doc id does not exist or the user does not have permission to access it or edit it
						   SET @data_validation_status = 'Fail';
						   SET @transaction_ready      = 'Fail';
						   EXEC internal.usp_SEL_message 
								@message_id = 'NoDocIDAccess', 
								@message_text = @tempmessage OUTPUT;
  						   IF @tempmessage IS NOT NULL 
							  SET @message = CONCAT(@message , ' | ', 'Document ID: ', LEFT(@documentid, 20), '... ', @tempmessage);
						   ELSE 
							  SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on NoDocIDAccess.'); 
						 END
				END


	  IF @recordid = 0
		 SET @recordid = NULL;

	 -- Authenticate the user for the given controller level document group
	 -- This also returns fail if the id does not exist
    EXEC [internal].[usp_AUTHENTICATE_cont_doc_grp]
	     @contr_doc_grp_to_check = @recordid,
		 @user_authentication_result_cep = @tempuserauth_status OUTPUT;
	  IF @tempuserauth_status = 'Fail'
		BEGIN  -- The user does not have permission for this action
			SET @data_validation_status = 'Fail';
			SET @transaction_ready      = 'Fail';
			EXEC internal.usp_SEL_message 
				@message_id   = 'InvalidConDocGrp', 
				@message_text = @tempmessage OUTPUT;
			IF (@tempmessage IS NOT NULL) 
  			   SET @message = CONCAT(@message, ' | ', ISNULL(@username, ''), '  ', @tempmessage);
			ELSE 
			   SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on InvalidConDocGrp');
		END

  -- Check if the record exists
  IF @data_validation_status = 'Pass'
  		 BEGIN  -- Check that the record id exists
			 IF NOT EXISTS (SELECT controller_doc_group_name_id
							  FROM xref.controller_doc_group_links 
							 WHERE controller_doc_group_name_id = @recordid
							       AND doc_id = @documentid) 
				 BEGIN -- Record id does not exist
				   SET @data_validation_status = 'Fail';
				   SET @transaction_ready      = 'Fail';
				   EXEC internal.usp_SEL_message 
						@message_id = 'NotExist', 
						@message_text = @tempmessage OUTPUT;
  				   IF (@tempmessage IS NOT NULL) 
					  SET @message = CONCAT_WS(' | ', @message, @tempmessage);
				   ELSE 
					  SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on NotExist.');
				 END
		 END





		  -- Output the failed data validation message
		  IF @data_validation_status = 'Fail'
			BEGIN
			  EXEC internal.usp_SEL_message 
				   @message_id   = 'FailedDataValidation', 
				   @message_text = @tempmessage OUTPUT;
			  IF @tempmessage IS NOT NULL 
				 SET @message = CONCAT_WS(' | ', @message, @tempmessage);
			  ELSE 
				 SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on FailedDataValidation.');
			END
		  -- End data validation
    END -- End IF user authentication = Pass
  
  -- Execute the insert query
  IF @transaction_ready = 'Ready'
	BEGIN
	  BEGIN TRY
	   BEGIN TRANSACTION;
	     DELETE FROM xref.controller_doc_group_links 
		  WHERE doc_id = @documentid
			    AND controller_doc_group_name_id = @recordid; 

			 -- Create an audit log entry
			   -- Select the SID ID for the connected user
			  SELECT @sidid = sl.sid_id
				FROM user_restr.sid_list AS sl
			   WHERE sl.sid = @connectedusersid;

			   SELECT @contrdocgroupname = attr_name
			     FROM xref.controller_doc_group_names
				WHERE controller_doc_group_name_id =  @recordid

	 			  IF EXISTS (SELECT gsg.file_doc_change_log
						   FROM base.global_settings_groups AS gsg
						  WHERE gsg.setting_group_name = 'Master'
							AND gsg.file_doc_change_log = 'On')
				   BEGIN
					 INSERT INTO base.file_doc_data_log
								 (created_by_username, created_by_sid_id, change_type, change_field,  doc_id,     
								  record_id,    record_name, original_value, new_value, notes, app_reference)
						  VALUES (@username,           @sidid,            'Delete',    'Document to Controller Document Group Link',  @documentid,   
								  @recordid, @contrdocgroupname, @contrdocgroupname,           NULL, @notes, @app_reference)
				   END	  

	   COMMIT TRANSACTION;
         EXEC internal.usp_SEL_message 
              @message_id   = 'Success', 
              @message_text = @tempmessage OUTPUT;
  	          IF (@tempmessage IS NOT NULL) 
	             SET @message = CONCAT_WS(' | ', @message, @tempmessage);
	          ELSE 
			     SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on Success.');
		 SET @transaction_status = 'Good';
   	  END TRY
	  BEGIN CATCH

	     IF XACT_STATE() <> 0
            ROLLBACK TRANSACTION;
	  	 
	     SET @transaction_status = 'Bad';
         EXEC internal.usp_SEL_message 
              @message_id   = 'DeleteError', 
              @message_text = @tempmessage OUTPUT;
		 IF (@tempmessage IS NOT NULL) 
		   SET @message = CONCAT(@message, ' | ', @tempmessage, ' | ', 
		   CONVERT(nvarchar(10),ERROR_NUMBER()), ' | ', ERROR_MESSAGE());
		 ELSE 
		   SET @message = CONCAT_WS(' | ', @message, 'A database level message error occurred on DeleteError.');
	  END CATCH
    END

END
GO
